Delegate ステートメント

デリゲートを宣言するために使用されます。 デリゲートは、型の Shared メソッドまたはオブジェクトのインスタンス メソッドを参照する参照型です。 パラメーターと戻り値の型が一致するすべてのプロシージャを使用して、このデリゲート クラスのインスタンスを作成できます。 その後、デリゲート インスタンスを使用してプロシージャを呼び出すことができます。

構文

[ <attrlist> ] [ accessmodifier ] _  
[ Shadows ] Delegate [ Sub | Function ] name [( Of typeparamlist )] [([ parameterlist ])] [ As type ]  

部品

注釈

Delegate ステートメントは、デリゲート クラスのパラメーターと戻り値の型を定義します。 パラメーターと戻り値の型が一致するすべてのプロシージャを使用して、このデリゲート クラスのインスタンスを作成できます。 その後、デリゲートの Invoke メソッドを呼び出すことで、デリゲート インスタンスを使用してプロシージャを呼び出すことができます。

デリゲートは、名前空間、モジュール、クラス、または構造体レベルで宣言できますが、プロシージャ内では宣言できません。

各デリゲート クラスは、オブジェクト メソッドの仕様に渡されるコンストラクターを定義します。 デリゲート コンストラクターの引数は、メソッドまたはラムダ式への参照である必要があります。

メソッドへの参照を指定するには、次の構文を使用します。

AddressOf [expression.]methodname

expressionのコンパイル時の型は、デリゲート クラスのシグネチャと一致するシグネチャを持つ、指定した名前のメソッドを含むクラスまたはインターフェイスの名前である必要があります。 methodnameには、共有メソッドまたはインスタンス メソッドのいずれかを指定できます。 クラスの既定のメソッドのデリゲートを作成する場合でも、 methodname は省略可能ではありません。

ラムダ式を指定するには、次の構文を使用します。

Function ([parm As type, parm2 As type2, ...]) expression

関数のシグネチャは、デリゲート型のシグネチャと一致する必要があります。 ラムダ式の詳細については、「 ラムダ式」を参照してください。

デリゲートの詳細については、「 デリゲート」を参照してください。

例

次の例では、 Delegate ステートメントを使用して、2 つの数値を操作し、数値を返すデリゲートを宣言します。 DelegateTest メソッドは、この型のデリゲートのインスタンスを受け取り、それを使用して数値のペアを操作します。

Delegate Function MathOperator( 
    ByVal x As Double, 
    ByVal y As Double 
) As Double

Function AddNumbers( 
    ByVal x As Double, 
    ByVal y As Double 
) As Double
    Return x + y
End Function

Function SubtractNumbers( 
    ByVal x As Double, 
    ByVal y As Double
) As Double
    Return x - y
End Function

Sub DelegateTest( 
    ByVal x As Double, 
    ByVal op As MathOperator, 
    ByVal y As Double 
)
    Dim ret As Double
    ret = op.Invoke(x, y) ' Call the method.
    MsgBox(ret)
End Sub

Protected Sub Test()
    DelegateTest(5, AddressOf AddNumbers, 3)
    DelegateTest(9, AddressOf SubtractNumbers, 3)
End Sub

こちらも参照ください

• AddressOf 演算子
• Of
• 代表者
• 方法: ジェネリック クラスを使用する
• Visual Basic のジェネリック型
• 共変性と反変性
• で
• アウト