Поделиться через

Использование дисперсии в делегатах (Visual Basic)

При назначении метода делегату ковариация и контравариантность обеспечивают гибкость сопоставления типа делегата с сигнатурой метода. Ковариация позволяет методу иметь тип возвращаемого значения, который является более производным, чем определенный в делегате. Контравариантность допускает использование метода, параметры которого имеют типы, менее производные, чем типы в делегате.

Пример 1. Ковариация

Описание

В этом примере показано, как делегаты могут использоваться с методами, имеющими типы возвращаемых данных, производные от возвращаемого типа в сигнатуре делегата. Тип данных, возвращаемый DogsHandler, имеет тип Dogs, который является производным от типа Mammals, определенного в делегате.

Код

Class Mammals
End Class

Class Dogs
    Inherits Mammals
End Class
Class Test
    Public Delegate Function HandlerMethod() As Mammals
    Public Shared Function MammalsHandler() As Mammals
        Return Nothing
    End Function
    Public Shared Function DogsHandler() As Dogs
        Return Nothing
    End Function
    Sub Test()
        Dim handlerMammals As HandlerMethod = AddressOf MammalsHandler
        ' Covariance enables this assignment.
        Dim handlerDogs As HandlerMethod = AddressOf DogsHandler
    End Sub
End Class

Пример 2. Контравариантность

Описание

В этом примере показано, как делегаты могут использоваться с методами, имеющими параметры, типы которых являются базовыми типами типа параметра подписи делегата. С помощью контравариантности можно использовать один обработчик событий вместо отдельных обработчиков. В следующем примере используется два делегата:

  • Делегат KeyEventHandler, определяющий сигнатуру события Button.KeyDown. Его подпись:

    Public Delegate Sub KeyEventHandler(sender As Object, e As KeyEventArgs)

  • Делегат MouseEventHandler, определяющий сигнатуру события Button.MouseClick. Его подпись:

    Public Delegate Sub MouseEventHandler(sender As Object, e As MouseEventArgs)

В примере определяется обработчик событий с параметром EventArgs, который используется для обработки как события Button.KeyDown, так и события Button.MouseClick. Это может сделать, так как EventArgs это базовый тип обоих KeyEventArgs и MouseEventArgs.

Код

' Event handler that accepts a parameter of the EventArgs type.
Private Sub MultiHandler(ByVal sender As Object,
                         ByVal e As System.EventArgs)
    Label1.Text = DateTime.Now
End Sub

Private Sub Form1_Load(ByVal sender As System.Object,
    ByVal e As System.EventArgs) Handles MyBase.Load

    ' You can use a method that has an EventArgs parameter,
    ' although the event expects the KeyEventArgs parameter.
    AddHandler Button1.KeyDown, AddressOf MultiHandler

    ' You can use the same method
    ' for the event that expects the MouseEventArgs parameter.
    AddHandler Button1.MouseClick, AddressOf MultiHandler
End Sub

См. также