Поделиться через

Использование вариативности для Func и универсальных делегатов действий (Visual Basic)

В этих примерах показано, как использовать ковариацию и контравариацию в Func и Action универсальных делегатах, чтобы включить повторное использование методов и обеспечить большую гибкость в коде.

Дополнительные сведения о ковариации и контравариации см. раздел "Ковариантность в делегатах (Visual Basic)".

Использование делегатов с ковариантными параметрами типа

В следующем примере показаны преимущества поддержки ковариации в обобщённых Func делегатах. Метод FindByTitle принимает параметр String типа и возвращает объект Employee типа. Однако этот метод можно назначить делегату Func(Of String, Person) , так как Employee наследует Person.

' Simple hierarchy of classes.
Public Class Person
End Class

Public Class Employee
    Inherits Person
End Class

Class Finder
    Public Shared Function FindByTitle(
        ByVal title As String) As Employee
        ' This is a stub for a method that returns
        ' an employee that has the specified title.
        Return New Employee
    End Function

    Sub Test()
        ' Create an instance of the delegate without using variance.
        Dim findEmployee As Func(Of String, Employee) =
            AddressOf FindByTitle

        ' The delegate expects a method to return Person,
        ' but you can assign it a method that returns Employee.
        Dim findPerson As Func(Of String, Person) =
            AddressOf FindByTitle

        ' You can also assign a delegate
        ' that returns a more derived type to a delegate
        ' that returns a less derived type.
        findPerson = findEmployee
    End Sub
End Class

Использование делегатов с контравариантными параметрами типа

В следующем примере показаны преимущества поддержки контравариантности в универсальных Action делегатах. Метод AddToContacts принимает параметр Person типа. Однако этот метод можно назначить делегату Action(Of Employee) , так как Employee наследует Person.

Public Class Person
End Class

Public Class Employee
    Inherits Person
End Class

Class AddressBook
    Shared Sub AddToContacts(ByVal person As Person)
        ' This method adds a Person object
        ' to a contact list.
    End Sub

    Sub Test()
        ' Create an instance of the delegate without using variance.
        Dim addPersonToContacts As Action(Of Person) =
            AddressOf AddToContacts

        ' The Action delegate expects
        ' a method that has an Employee parameter,
        ' but you can assign it a method that has a Person parameter
        ' because Employee derives from Person.
        Dim addEmployeeToContacts As Action(Of Employee) =
            AddressOf AddToContacts

        ' You can also assign a delegate
        ' that accepts a less derived parameter
        ' to a delegate that accepts a more derived parameter.
        addEmployeeToContacts = addPersonToContacts
    End Sub
End Class

См. также