下表列出了 Visual Basic 在 Microsoft.VisualBasic.Strings 类中用于搜索和作字符串的函数。 它们可以视为 Visual Basic 内部函数;也就是说，无需将它们作为类的显式成员调用，如示例所示。 其他方法（在某些情况下是补充方法）在类中 System.String 可用。
| .NET Framework 方法 | DESCRIPTION |
|---|---|
| Asc、AscW | 返回一个 Integer 值，该值表示与字符对应的字符代码。 |
| Chr、ChrW | 返回与指定字符代码关联的字符。 |
| Filter | 返回一个从零开始的数组，该数组包含基于指定筛选条件的 String 数组子集。 |
| Format | 根据格式 String 表达式中包含的说明返回格式化的字符串。 |
| FormatCurrency | 使用系统控制面板中定义的货币符号返回格式化为货币值的表达式。 |
| FormatDateTime | 返回表示日期/时间值的字符串表达式。 |
| FormatNumber | 返回格式化为数字的表达式。 |
| FormatPercent | 返回格式化为百分比（即乘以 100）的表达式，其尾随 % 字符。 |
| InStr | 返回一个整数，该值指定一个字符串在另一个字符串中的第一个匹配项的起始位置。 |
| InStrRev | 返回从字符串右侧开始的另一个字符串的第一个匹配项的位置。 |
| Join | 返回通过联接数组中包含的多个子字符串创建的字符串。 |
| LCase | 返回转换为小写的字符串或字符。 |
| Left | 返回一个字符串，该字符串包含字符串左侧的指定字符数。 |
| Len | 返回一个整数，其中包含字符串中的字符数。 |
| LSet | 返回一个左对齐的字符串，该字符串包含调整为指定长度的指定字符串。 |
| LTrim | 返回一个字符串，其中包含没有前导空格的指定字符串的副本。 |
| Mid | 返回包含字符串中指定数量的字符的字符串。 |
| Replace | 返回一个字符串，其中指定的子字符串已替换为指定次数的另一个子字符串。 |
| Right | 返回一个字符串，该字符串包含字符串右侧的指定字符数。 |
| RSet | 返回一个右对齐的字符串，该字符串包含调整为指定长度的指定字符串。 |
| RTrim | 返回一个字符串，其中包含没有尾随空格的指定字符串的副本。 |
| Space | 返回一个字符串，该字符串由指定的空格数组成。 |
| Split | 返回包含指定数量的子字符串的从零开始的一维数组。 |
| StrComp | 根据字符串比较的结果返回 -1、0 或 1。 |
| StrConv | 返回按指定转换的字符串。 |
| StrDup | 返回由指定字符组成的字符串或对象重复指定的次数。 |
| StrReverse | 返回一个字符串，其中指定字符串的字符顺序是反向的。 |
| Trim | 返回一个字符串，其中包含没有前导或尾随空格的指定字符串的副本。 |
| UCase | 返回包含转换为大写的指定字符串的字符串或字符。 |
可以使用 Option Compare 语句设置字符串是使用系统的区域设置（Text）确定的不区分大小写的文本排序顺序还是由字符的内部二进制表示形式（Binary）进行比较。 默认文本比较方法为 Binary。
示例：UCase
此示例使用 UCase 函数返回字符串的大写版本。
' String to convert.
Dim lowerCase As String = "Hello World 1234"
' Returns "HELLO WORLD 1234".
Dim upperCase As String = UCase(lowerCase)
示例：LTrim
此示例使用 LTrim 函数去除前导空格， RTrim 并使用函数从字符串变量中去除尾随空格。 它使用 Trim 函数来去除这两种类型的空格。
' Initializes string.
Dim testString As String = " <-Trim-> "
Dim trimString As String
' Returns "<-Trim-> ".
trimString = LTrim(testString)
' Returns " <-Trim->".
trimString = RTrim(testString)
' Returns "<-Trim->".
trimString = LTrim(RTrim(testString))
' Using the Trim function alone achieves the same result.
' Returns "<-Trim->".
trimString = Trim(testString)
示例：Mid
此示例使用 Mid 函数从字符串中返回指定数量的字符。
' Creates text string.
Dim testString As String = "Mid Function Demo"
' Returns "Mid".
Dim firstWord As String = Mid(testString, 1, 3)
' Returns "Demo".
Dim lastWord As String = Mid(testString, 14, 4)
' Returns "Function Demo".
Dim midWords As String = Mid(testString, 5)
示例：Len
此示例用于 Len 返回字符串中的字符数。
' Initializes variable.
Dim testString As String = "Hello World"
' Returns 11.
Dim testLen As Integer = Len(testString)
示例：InStr
此示例使用 InStr 函数返回第一个字符串在另一个字符串中出现的位置。
' String to search in.
Dim searchString As String = "XXpXXpXXPXXP"
' Search for "P".
Dim searchChar As String = "P"
Dim testPos As Integer
' A textual comparison starting at position 4. Returns 6.
testPos = InStr(4, searchString, searchChar, CompareMethod.Text)
' A binary comparison starting at position 1. Returns 9.
testPos = InStr(1, SearchString, SearchChar, CompareMethod.Binary)
' If Option Compare is not set, or set to Binary, return 9.
' If Option Compare is set to Text, returns 3.
testPos = InStr(searchString, searchChar)
' Returns 0.
testPos = InStr(1, searchString, "W")
示例：格式
此示例显示了函数的各种 Format 用法，以使用 String 格式和用户定义的格式设置值的格式。 对于日期分隔符（）、时间分隔符（/:）和 AM/PM 指示器（t以及tt），系统显示的实际格式化输出取决于代码正在使用的区域设置。 在开发环境中显示时间和日期时，将使用代码区域设置的短时间格式和短日期格式。
注释
对于使用 24 小时制的区域设置，AM/PM 指示器（t 和 tt）不显示任何内容。
Dim testDateTime As Date = #1/27/2001 5:04:23 PM#
Dim testStr As String
' Returns current system time in the system-defined long time format.
testStr = Format(Now(), "Long Time")
' Returns current system date in the system-defined long date format.
testStr = Format(Now(), "Long Date")
' Also returns current system date in the system-defined long date
' format, using the single letter code for the format.
testStr = Format(Now(), "D")
' Returns the value of testDateTime in user-defined date/time formats.
' Returns "5:4:23".
testStr = Format(testDateTime, "h:m:s")
' Returns "05:04:23 PM".
testStr = Format(testDateTime, "hh:mm:ss tt")
' Returns "Saturday, Jan 27 2001".
testStr = Format(testDateTime, "dddd, MMM d yyyy")
' Returns "17:04:23".
testStr = Format(testDateTime, "HH:mm:ss")
' Returns "23".
testStr = Format(23)
' User-defined numeric formats.
' Returns "5,459.40".
testStr = Format(5459.4, "##,##0.00")
' Returns "334.90".
testStr = Format(334.9, "###0.00")
' Returns "500.00%".
testStr = Format(5, "0.00%")
