Поделиться через

Практическое руководство. Запрос к крупнейшему файлу или файлам в дереве каталогов (LINQ) (Visual Basic)

В этом примере показаны пять запросов, связанных с размером файла в байтах:

  • Как получить размер в байтах крупнейшего файла.

  • Как получить размер в байтах наименьшего файла.

  • Как получить самый большой или наименьший FileInfo файл объекта из одной или нескольких папок в указанной корневой папке.

  • Как получить последовательность, например 10 крупнейших файлов.

  • Как упорядочить файлы в группы на основе их размера в байтах, игнорируя файлы, которые меньше указанного размера.

Пример

В следующем примере содержатся пять отдельных запросов, которые показывают, как запрашивать и группировать файлы в зависимости от размера файла в байтах. Эти примеры можно легко изменить, чтобы создать запрос на другое свойство FileInfo объекта.

Module QueryBySize  
    Sub Main()  
  
        ' Change the drive\path if necessary  
        Dim root As String = "C:\Program Files\Microsoft Visual Studio 9.0"  
  
        'Take a snapshot of the folder contents  
        Dim dir As New System.IO.DirectoryInfo(root)  
        Dim fileList = dir.GetFiles("*.*", System.IO.SearchOption.AllDirectories)  
  
        ' Return the size of the largest file  
        Dim maxSize = Aggregate aFile In fileList Into Max(GetFileLength(aFile))  
  
        'Dim maxSize = fileLengths.Max  
        Console.WriteLine("The length of the largest file under {0} is {1}", _  
                          root, maxSize)  
  
        ' Return the FileInfo object of the largest file  
        ' by sorting and selecting from the beginning of the list  
        Dim filesByLengDesc = From file In fileList _  
                              Let filelength = GetFileLength(file) _  
                              Where filelength > 0 _  
                              Order By filelength Descending _  
                              Select file  
  
        Dim longestFile = filesByLengDesc.First  
  
        Console.WriteLine("The largest file under {0} is {1} with a length of {2} bytes", _  
                          root, longestFile.FullName, longestFile.Length)  
  
        Dim smallestFile = filesByLengDesc.Last  
  
        Console.WriteLine("The smallest file under {0} is {1} with a length of {2} bytes", _  
                                root, smallestFile.FullName, smallestFile.Length)  
  
        ' Return the FileInfos for the 10 largest files  
        ' Based on a previous query, but nothing is executed  
        ' until the For Each statement below.  
        Dim tenLargest = From file In filesByLengDesc Take 10  
  
        Console.WriteLine("The 10 largest files under {0} are:", root)  
  
        For Each fi As System.IO.FileInfo In tenLargest  
            Console.WriteLine("{0}: {1} bytes", fi.FullName, fi.Length)  
        Next  
  
        ' Group files according to their size,  
        ' leaving out the ones under 200K  
        Dim sizeGroups = From file As System.IO.FileInfo In fileList _  
                         Where file.Length > 0 _  
                         Let groupLength = file.Length / 100000 _  
                         Group file By groupLength Into fileGroup = Group _  
                         Where groupLength >= 2 _  
                         Order By groupLength Descending  
  
        For Each group In sizeGroups  
            Console.WriteLine(group.groupLength + "00000")  
  
            For Each item As System.IO.FileInfo In group.fileGroup  
                Console.WriteLine("   {0}: {1}", item.Name, item.Length)  
            Next  
        Next  
  
        ' Keep the console window open in debug mode  
        Console.WriteLine("Press any key to exit.")  
        Console.ReadKey()  
  
    End Sub  
  
    ' This method is used to catch the possible exception  
    ' that can be raised when accessing the FileInfo.Length property.  
    ' In this particular case, it is safe to ignore the exception.  
    Function GetFileLength(ByVal fi As System.IO.FileInfo) As Long  
        Dim retval As Long  
        Try  
            retval = fi.Length  
        Catch ex As FileNotFoundException  
            ' If a file is no longer present,  
            ' just return zero bytes.
            retval = 0  
        End Try  
  
        Return retval  
    End Function  
End Module

Чтобы вернуть один или несколько полных FileInfo объектов, запрос сначала должен проверить каждый из них в источнике данных, а затем отсортировать их по значению свойства Length. Затем он может вернуть одну или последовательность с наибольшей длиной. Используется First для возврата первого элемента в списке. Используется Take для возврата первого n числа элементов. Укажите порядок сортировки по убыванию, чтобы поместить наименьшие элементы в начало списка.

Запрос вызывает отдельный метод, чтобы получить размер файла в байтах и обработать возможное исключение, которое будет возникать в случае удаления файла в другом потоке с момента создания объекта FileInfo при вызове GetFiles. Даже если объект FileInfo уже создан, исключение может возникнуть, так как объект FileInfo попытается обновить свое свойство Length, используя самый актуальный размер в байтах при первом обращении к свойству. Поместив эту операцию в блок try-catch вне запроса, мы следуем правилу избегания операций внутри запросов, которые могут вызвать побочные эффекты. Как правило, при обработке исключений необходимо соблюдать большую осторожность, чтобы убедиться, что приложение не попадает в состояние неопределенности.

Компиляция кода

Создайте проект консольного приложения Visual Basic с инструкцией Imports для пространства имен System.Linq.

См. также