Поделиться через

Как выполнять запрос символьных данных в строке (LINQ) (Visual Basic)

String Так как класс реализует универсальный IEnumerable<T> интерфейс, любая строка может запрашиваться в виде последовательности символов. Однако это не обычное использование LINQ. Для сложных операций сопоставления шаблонов используйте Regex класс.

Пример

В следующем примере выполняется запрос строки для определения количества числовых цифр, содержащихся в нем. Обратите внимание, что запрос "повторно используется" после первого выполнения. Это возможно, так как сам запрос не сохраняет фактические результаты.

Class QueryAString

    Shared Sub Main()

        ' A string is an IEnumerable data source.
        Dim aString As String = "ABCDE99F-J74-12-89A"

        ' Select only those characters that are numbers
        Dim stringQuery = From ch In aString
                          Where Char.IsDigit(ch)
                          Select ch
        ' Execute the query
        For Each c As Char In stringQuery
            Console.Write(c & " ")
        Next

        ' Call the Count method on the existing query.
        Dim count As Integer = stringQuery.Count()
        Console.WriteLine(System.Environment.NewLine & "Count = " & count)

        ' Select all characters before the first '-'
        Dim stringQuery2 = aString.TakeWhile(Function(c) c <> "-")

        ' Execute the second query
        For Each ch In stringQuery2
            Console.Write(ch)
        Next

        Console.WriteLine(System.Environment.NewLine & "Press any key to exit")
        Console.ReadKey()
    End Sub
End Class
' Output:
' 9 9 7 4 1 2 8 9
' Count = 8
' ABCDE99F

Компиляция кода

Создайте проект консольного приложения Visual Basic с инструкцией Imports для пространства имен System.Linq.

См. также