Поделиться через

Практическое руководство. Запрос массива с помощью LINQ (Visual Basic)

При использовании LINQ для запроса не универсальных IEnumerable коллекций, таких как ArrayList, необходимо явно объявить тип переменной диапазона, чтобы отразить конкретный тип объектов в коллекции. Например, если у вас есть ArrayListStudent объекты, предложение From должно выглядеть следующим образом:

Dim query = From student As Student In arrList
'...

Задав тип переменной диапазона, вы приводите каждый элемент в ArrayList к типу Student.

Использование явно типизированной переменной диапазона в выражении запроса эквивалентно вызову Cast метода. Cast вызывает исключение, если не удается выполнить указанное приведение. Cast и OfType являются двумя методами оператора стандартных запросов, которые работают с не универсальными IEnumerable типами. В Visual Basic необходимо явно вызвать Cast метод в источнике данных, чтобы обеспечить определенный тип переменной диапазона. Дополнительные сведения см. в разделе "Связи типов" в операциях запросов (Visual Basic).

Пример

В следующем примере показан простой запрос по объекту ArrayList. Обратите внимание, что в этом примере используются инициализаторы объектов, когда код вызывает Add метод, но это не обязательно.

Imports System.Collections
Imports System.Linq

Module Module1

    Public Class Student
        Public Property FirstName As String
        Public Property LastName As String
        Public Property Scores As Integer()
    End Class

    Sub Main()

        Dim student1 As New Student With {.FirstName = "Svetlana",
                                     .LastName = "Omelchenko",
                                     .Scores = New Integer() {98, 92, 81, 60}}
        Dim student2 As New Student With {.FirstName = "Claire",
                                    .LastName = "O'Donnell",
                                    .Scores = New Integer() {75, 84, 91, 39}}
        Dim student3 As New Student With {.FirstName = "Cesar",
                                    .LastName = "Garcia",
                                    .Scores = New Integer() {97, 89, 85, 82}}
        Dim student4 As New Student With {.FirstName = "Sven",
                                    .LastName = "Mortensen",
                                    .Scores = New Integer() {88, 94, 65, 91}}

        Dim arrList As New ArrayList()
        arrList.Add(student1)
        arrList.Add(student2)
        arrList.Add(student3)
        arrList.Add(student4)

        ' Use an explicit type for non-generic collections
        Dim query = From student As Student In arrList
                    Where student.Scores(0) > 95
                    Select student

        For Each student As Student In query
            Console.WriteLine(student.LastName & ": " & student.Scores(0))
        Next
        ' Keep the console window open in debug mode.
        Console.WriteLine("Press any key to exit.")
        Console.ReadKey()
    End Sub

End Module
' Output:
'   Omelchenko: 98
'   Garcia: 97

См. также