Поделиться через

Доступ к атрибутам с помощью отражения (Visual Basic)

Тот факт, что вы можете определить настраиваемые атрибуты и поместить их в исходный код, не будет иметь небольшого значения без какого-то способа получения этой информации и действия над ним. С помощью отражения можно получить сведения, определенные с помощью пользовательских атрибутов. Ключевым методом является GetCustomAttributes, который возвращает массив объектов, которые являются эквивалентами времени выполнения атрибутов исходного кода. Этот метод имеет несколько перегруженных версий. Дополнительные сведения см. в разделе Attribute.

Спецификация атрибута, например:

<Author("P. Ackerman", Version:=1.1)>
Class SampleClass
    ' P. Ackerman's code goes here...
End Class

концептуально эквивалентен этому:

Dim anonymousAuthorObject As Author = New Author("P. Ackerman")
anonymousAuthorObject.version = 1.1

Однако код не выполняется, пока SampleClass не будет запрашивать атрибуты. Вызов GetCustomAttributes на SampleClass приводит к созданию и инициализации объекта Author так, как описано выше. Если класс имеет другие атрибуты, другие объекты атрибутов создаются аналогичным образом. GetCustomAttributes затем возвращает Author объект и любые другие объекты атрибутов в массиве. Затем можно выполнить итерацию по этому массиву, определить, какие атрибуты были применены на основе типа каждого элемента массива, а также извлечь сведения из объектов атрибутов.

Пример

Ниже приведен полный пример. Настраиваемый атрибут определяется, применяется к нескольким сущностям и извлекается с помощью отражения.

' Multiuse attribute
<System.AttributeUsage(System.AttributeTargets.Class Or
                       System.AttributeTargets.Struct,
                       AllowMultiple:=True)>
Public Class Author
    Inherits System.Attribute
    Private name As String
    Public version As Double
    Sub New(ByVal authorName As String)
        name = authorName

        ' Default value
        version = 1.0
    End Sub

    Function GetName() As String
        Return name
    End Function
End Class

' Class with the Author attribute
<Author("P. Ackerman")>
Public Class FirstClass
End Class

' Class without the Author attribute
Public Class SecondClass
End Class

' Class with multiple Author attributes.
<Author("P. Ackerman"), Author("R. Koch", Version:=2.0)>
Public Class ThirdClass
End Class

Class TestAuthorAttribute
    Sub Main()
        PrintAuthorInfo(GetType(FirstClass))
        PrintAuthorInfo(GetType(SecondClass))
        PrintAuthorInfo(GetType(ThirdClass))
    End Sub

    Private Shared Sub PrintAuthorInfo(ByVal t As System.Type)
        System.Console.WriteLine("Author information for {0}", t)

        ' Using reflection
        Dim attrs() As System.Attribute = System.Attribute.GetCustomAttributes(t)

        ' Displaying output
        For Each attr In attrs
            Dim a As Author = CType(attr, Author)
            System.Console.WriteLine("   {0}, version {1:f}", a.GetName(), a.version)
        Next
    End Sub

    ' Output:
    '   Author information for FirstClass
    '     P. Ackerman, version 1.00
    ' Author information for SecondClass
    ' Author information for ThirdClass
    '  R. Koch, version 2.00
    '  P. Ackerman, version 1.00

End Class

См. также