Оператор события

Объявляет определяемое пользователем событие.

Синтаксис

[ <attrlist> ] [ accessmodifier ] _  
[ Shared ] [ Shadows ] Event eventname[(parameterlist)] _  
[ Implements implementslist ]  
' -or-  
[ <attrlist> ] [ accessmodifier ] _  
[ Shared ] [ Shadows ] Event eventname As delegatename _  
[ Implements implementslist ]  
' -or-  
 [ <attrlist> ] [ accessmodifier ] _  
[ Shared ] [ Shadows ] Custom Event eventname As delegatename _  
[ Implements implementslist ]  
   [ <attrlist> ] AddHandler(ByVal value As delegatename)  
      [ statements ]  
   End AddHandler  
   [ <attrlist> ] RemoveHandler(ByVal value As delegatename)  
      [ statements ]  
   End RemoveHandler  
   [ <attrlist> ] RaiseEvent(delegatesignature)  
      [ statements ]  
   End RaiseEvent  
End Event  

Комплектующие

Замечания

После объявления события используйте RaiseEvent инструкцию для создания события. Обычное событие можно объявить и вызвать, как показано в следующих фрагментах:

Public Class EventSource
    ' Declare an event.
    Public Event LogonCompleted(ByVal UserName As String)
    Sub CauseEvent()
        ' Raise an event on successful logon.
        RaiseEvent LogonCompleted("AustinSteele")
    End Sub
End Class

Чтобы обработать событие, необходимо связать его с подпрограммой обработчика событий с помощью инструкции или AddHandler инструкцииHandles. Подписи подпрограммы и события должны совпадать. Для обработки общего события необходимо использовать инструкцию AddHandler .

Можно использовать Event только на уровне модуля. Это означает , что контекст объявления для события должен быть классом, структурой, модулем или интерфейсом и не может быть исходным файлом, пространством имен, процедурой или блоком. Дополнительные сведения см. в разделе "Контексты объявления" и "Уровни доступа по умолчанию".

В большинстве случаев можно использовать первый синтаксис в разделе синтаксиса этого раздела для объявления событий. Однако в некоторых сценариях требуется больше контроля над подробным поведением события. Последний синтаксис в разделе синтаксиса этого раздела, который использует Custom ключевое слово, предоставляет этот элемент управления, позволяя определять пользовательские события. В пользовательском событии вы указываете точно то, что происходит при добавлении или удалении обработчика событий в событие или при вызове события. Примеры см. в статье "Практическое руководство. Объявление настраиваемых событий для экономии памяти и практическое руководство. Объявление настраиваемых событий для предотвращения блокировки".

Пример

В следующем примере события используются для подсчета секунд от 10 до 0. Код иллюстрирует несколько методов, свойств и инструкций, связанных с событиями. К ним относится RaiseEvent инструкция.

Класс, который вызывает событие, является источником событий, а методы, обрабатывающие событие, являются обработчиками событий. Источник событий может содержать несколько обработчиков для событий, которые он создает. Когда класс вызывает событие, это событие вызывается на каждом классе, который выбрал для обработки событий для этого экземпляра объекта.

В примере также используется форма (Form1) с кнопкой (Button1) и текстовым полем (TextBox1). При нажатии кнопки в первом текстовом поле отображается отсчет от 10 до 0 секунд. Когда полный рабочий день (10 секунд) истек, в первом текстовом поле отображается "Готово".

Код для Form1 указания начальных и конечных состояний формы. Он также содержит код, выполняемый при порождении события.

Чтобы использовать этот пример, откройте новый проект Windows Forms. Затем добавьте кнопку с именем Button1 и текстовое поле с именем TextBox1Form1основной формы. Затем щелкните форму правой кнопкой мыши и щелкните "Просмотреть код ", чтобы открыть редактор кода.

WithEvents Добавьте переменную в раздел объявлений Form1 класса:

Private WithEvents mText As TimerState

Добавьте следующий код в код для Form1. Замените все повторяющиеся процедуры, которые могут существовать, например Form_Load или Button_Click.

Private Sub Form1_Load() Handles MyBase.Load
    Button1.Text = "Start"
    mText = New TimerState
End Sub
Private Sub Button1_Click() Handles Button1.Click
    mText.StartCountdown(10.0, 0.1)
End Sub

Private Sub mText_ChangeText() Handles mText.Finished
    TextBox1.Text = "Done"
End Sub

Private Sub mText_UpdateTime(ByVal Countdown As Double
  ) Handles mText.UpdateTime

    TextBox1.Text = Format(Countdown, "##0.0")
    ' Use DoEvents to allow the display to refresh.
    My.Application.DoEvents()
End Sub

Class TimerState
    Public Event UpdateTime(ByVal Countdown As Double)
    Public Event Finished()
    Public Sub StartCountdown(ByVal Duration As Double,
                              ByVal Increment As Double)
        Dim Start As Double = DateAndTime.Timer
        Dim ElapsedTime As Double = 0

        Dim SoFar As Double = 0
        Do While ElapsedTime < Duration
            If ElapsedTime > SoFar + Increment Then
                SoFar += Increment
                RaiseEvent UpdateTime(Duration - SoFar)
            End If
            ElapsedTime = DateAndTime.Timer - Start
        Loop
        RaiseEvent Finished()
    End Sub
End Class

Нажмите клавишу F5, чтобы запустить предыдущий пример, и нажмите кнопку " Пуск". Первое текстовое поле начинает отсчитывать секунды. Когда полный рабочий день (10 секунд) истек, в первом текстовом поле отображается "Готово".

См. также

• Оператор RaiseEvent
• Оператор Implements
• События
• Инструкция AddHandler
• Оператор RemoveHandler
• Обрабатывает
• Заявление Делегата
• Как объявить пользовательские события для экономии памяти
• Практическое руководство. Объявление пользовательских событий для предотвращения блокировки
• Shared
• Shadows