Utwórz grupę dostępności Always On przy użyciu Transact-SQL (T-SQL)

Dotyczy:SQL Server

Opisano tutaj, jak używać Transact-SQL do tworzenia i konfigurowania grupy dostępności w instancjach programu SQL Server, w których włączono funkcję grup dostępności Always On. Grupa dostępności definiuje zestaw baz danych użytkowników, który przejdzie w tryb failover jako pojedynczą jednostkę i zestaw partnerów trybu failover, znany jako repliki dostępności , które obsługują tryb failover.

Wymagania wstępne, ograniczenia i zalecenia

• Przed utworzeniem grupy dostępności sprawdź, czy wystąpienia programu SQL Server, które hostują repliki dostępności, znajdują się w innym węźle Klastra trybu failover systemu Windows Server (WSFC) w tym samym klastrze trybu failover WSFC. Sprawdź również, czy każde wystąpienie serwera spełnia wszystkie inne wymagania wstępne dotyczące zawsze włączonych grup dostępności. Aby uzyskać więcej informacji, zdecydowanie zalecamy przeczytanie Wymagania Wstępne, Ograniczenia i Rekomendacje dotyczące Grup Dostępności Always On (SQL Server).

Uprawnienia

Wymaga członkostwa w sysadmin stałej roli serwera oraz jednego z następujących uprawnień: uprawnienie do utworzenia grupy dostępności, uprawnienie do zmiany dowolnej grupy dostępności lub kontrola serwera.

Tworzenie i konfigurowanie grupy dostępności przy użyciu Transact-SQL

Podsumowanie zadań i odpowiadających im stwierdzeń Transact-SQL

W poniższej tabeli wymieniono podstawowe zadania związane z tworzeniem i konfigurowaniem grupy dostępności oraz wskazuje, które instrukcje Transact-SQL należy użyć do realizacji tych zadań. Zadania Always On grup dostępności muszą być wykonywane w kolejności, w jakiej są przedstawione w tabeli.

Aby wykonać określone zadanie, połącz się ze wskazaną instancją serwera lub instancjami.

Korzystanie z Transact-SQL

1. Połącz się z wystąpieniem serwera, które ma hostować replikę podstawową.

2. Utwórz grupę dostępności przy użyciu instrukcji CREATE AVAILABILITY GROUPTransact-SQL.

3. Dołącz nową replikę wtórną do grupy dostępności. Aby uzyskać więcej informacji, zobacz Dołączanie repliki pomocniczej do grupy dostępności (SQL Server).

4. Dla każdej bazy danych w grupie dostępności utwórz pomocniczą bazę danych, przywracając najnowsze kopie zapasowe podstawowej bazy danych przy użyciu funkcji RESTORE WITH NORECOVERY. Aby uzyskać więcej informacji, zobacz Przykład: Konfigurowanie grupy dostępności przy użyciu uwierzytelniania systemu Windows (Transact-SQL), począwszy od kroku, który przywraca kopię zapasową bazy danych.

5. Dołącz każdą nową pomocniczą bazę danych do grupy dostępności. Aby uzyskać więcej informacji, zobacz Dołączanie repliki pomocniczej do grupy dostępności (SQL Server).

Przykład: konfigurowanie grupy dostępności korzystającej z uwierzytelniania systemu Windows

W tym przykładzie utworzono przykładową procedurę konfiguracji grup dostępności Always On, która używa Transact-SQL do konfigurowania punktów końcowych mirroringu bazy danych korzystających z uwierzytelniania systemu Windows, a także do tworzenia i konfigurowania grupy dostępności oraz jej pomocniczych baz danych.

Ten przykład zawiera następujące sekcje:

• Wymagania wstępne dotyczące korzystania z przykładowej procedury konfiguracji

• Przykładowa procedura konfiguracji

• Kompletny przykład kodu dla przykładowej procedury konfiguracji

Wymagania wstępne dotyczące korzystania z przykładowej procedury konfiguracji

Ta przykładowa procedura ma następujące wymagania:

• Wystąpienia serwera muszą obsługiwać grupy dostępności Always On. Aby uzyskać więcej informacji, zobacz Wymagania Wstępne, Ograniczenia i Zalecenia dla Grup Dostępności Always On (SQL Server).

• W wystąpieniu serwera muszą istnieć dwie przykładowe bazy danych MyDb1 i MyDb2, które będą hostować replikę podstawową. Poniższe przykłady kodu tworzą i konfigurują te dwie bazy danych oraz tworzą pełną kopię zapasową każdego z nich. Wykonaj te przykłady kodu w wystąpieniu serwera, w którym zamierzasz utworzyć przykładową grupę dostępności. Ta instancja serwera będzie hostować początkową replikę podstawową przykładowej grupy dostępności.

  1. Poniższy przykład Transact-SQL tworzy te bazy danych i zmienia je tak, aby korzystały z pełnego modelu odzyskiwania:

     -- Create sample databases:  
     CREATE DATABASE MyDb1;  
     GO  
     ALTER DATABASE MyDb1 SET RECOVERY FULL;  
     GO  
     
     CREATE DATABASE MyDb2;  
     GO  
     ALTER DATABASE MyDb2 SET RECOVERY FULL;  
     GO  
     

  2. Poniższy przykład kodu tworzy pełną kopię zapasową bazy danych MyDb1 i MyDb2. W tym przykładzie kodu użyto fikcyjnego zasobu udostępnionego do kopii zapasowej \\FILESERVER\SQLbackups.

     -- Backup sample databases:  
     BACKUP DATABASE MyDb1   
     TO DISK = N'\\FILESERVER\SQLbackups\MyDb1.bak'   
         WITH FORMAT;  
     GO  
     
     BACKUP DATABASE MyDb2   
     TO DISK = N'\\FILESERVER\SQLbackups\MyDb2.bak'   
         WITH FORMAT;  
     GO  
     

[TopOfExample]

Przykładowa procedura konfiguracji

W tej przykładowej konfiguracji replika dostępności zostanie utworzona na dwóch niezależnych wystąpieniach serwera, których konta usług działają w różnych, ale zaufanych domenach (DOMAIN1 i DOMAIN2).

Poniższa tabela zawiera podsumowanie wartości używanych w tej przykładowej konfiguracji.

1. Utwórz punkt końcowy dublowania bazy danych o nazwie dbm_endpoint w wystąpieniu serwera na którym planujesz utworzyć grupę wysokiej dostępności (jest to wystąpienie o nazwie AgHostInstance na COMPUTER01). Ten punkt końcowy używa portu 7022. Należy pamiętać, że instancja serwera, na której tworzysz grupę dostępności, będzie obsługiwać replikę podstawową.

   -- Create endpoint on server instance that hosts the primary replica:  
   CREATE ENDPOINT dbm_endpoint  
       STATE=STARTED   
       AS TCP (LISTENER_PORT=7022)   
       FOR DATABASE_MIRRORING (ROLE=ALL);  
   GO  
   

2. Utwórz punkt końcowy dbm_endpoint w wystąpieniu serwera, który będzie hostować replikę pomocniczą (jest to domyślne wystąpienie serwera w programie COMPUTER02). Ten punkt końcowy używa portu 5022.

   -- Create endpoint on server instance that hosts the secondary replica:   
   CREATE ENDPOINT dbm_endpoint  
       STATE=STARTED   
       AS TCP (LISTENER_PORT=5022)   
       FOR DATABASE_MIRRORING (ROLE=ALL);  
   GO  
   

3. Uwaga / Notatka

   Jeśli konta usług wystąpień serwera, które mają hostować repliki dostępności, działają na tym samym koncie domenowym, ten krok jest niepotrzebny. Pomiń go i przejdź bezpośrednio do następnego kroku.

   Jeśli konta usług wystąpień serwera działają pod różnymi użytkownikami domeny, w każdym wystąpieniu serwera utwórz login dla innego wystąpienia serwera i przyznaj temu loginowi uprawnienia dostępu do lokalnego punktu końcowego dublowania danych.

   Poniższy przykład kodu pokazuje instrukcje Transact-SQL dotyczące tworzenia loginu i nadawania mu uprawnień na punkcie końcowym. Konto domeny wystąpienia zdalnego serwera jest tutaj reprezentowane jako domain_name\user_name.

   -- If necessary, create a login for the service account, domain_name\user_name  
   -- of the server instance that will host the other replica:  
   USE master;  
   GO  
   CREATE LOGIN [domain_name\user_name] FROM WINDOWS;  
   GO  
   -- And Grant this login connect permissions on the endpoint:  
   GRANT CONNECT ON ENDPOINT::dbm_endpoint   
      TO [domain_name\user_name];  
   GO  
   

4. Utwórz grupę dostępności na instancji serwera, na której znajdują się bazy danych użytkowników.

   Poniższy przykład kodu tworzy grupę dostępności o nazwie MyAG w wystąpieniu serwera, w którym utworzono przykładowe bazy danych MyDb1 i MyDb2. Najpierw określono lokalne wystąpienie serwera AgHostInstance na komputerze COMPUTER01. To wystąpienie będzie hostować początkową replikę podstawową. Instancja serwera zdalnego, która jest domyślną instancją serwera na COMPUTER02, została określona do hostowania dodatkowej repliki. Obie repliki dostępności są skonfigurowane do używania trybu zatwierdzania asynchronicznego z ręcznym przełączeniem awaryjnym (w przypadku replik zatwierdzania asynchronicznego ręczne przełączenie awaryjne oznacza wymuszone przełączenie z możliwością utraty danych).

   -- Create the availability group, MyAG:   
   CREATE AVAILABILITY GROUP MyAG   
      FOR   
         DATABASE MyDB1, MyDB2   
      REPLICA ON   
         'COMPUTER01\AgHostInstance' WITH   
            (  
            ENDPOINT_URL = 'TCP://COMPUTER01.Adventure-Works.com:7022',   
            AVAILABILITY_MODE = ASYNCHRONOUS_COMMIT,  
            FAILOVER_MODE = MANUAL  
            ),  
         'COMPUTER02' WITH   
            (  
            ENDPOINT_URL = 'TCP://COMPUTER02.Adventure-Works.com:5022',  
            AVAILABILITY_MODE = ASYNCHRONOUS_COMMIT,  
            FAILOVER_MODE = MANUAL  
            );   
   GO  
   

   Aby uzyskać dodatkowe przykłady kodu Transact-SQL tworzenia grupy dostępności, zobacz CREATE AVAILABILITY GROUP (Transact-SQL).

5. Na instancji serwera, która hostuje replikę pomocniczą, dołącz tę replikę do grupy dostępności.

   Poniższy przykład kodu dołącza replikę pomocniczą na COMPUTER02 do grupy dostępności MyAG.

   -- On the server instance that hosts the secondary replica,   
   -- join the secondary replica to the availability group:  
   ALTER AVAILABILITY GROUP MyAG JOIN;  
   GO  
   

6. Utwórz bazy danych replik pomocniczych na wystąpieniu serwera obsługującym replikę pomocniczą.

   Poniższy przykład kodu tworzy pomocnicze bazy danych MyDb1 i MyDb2 przez przywrócenie kopii zapasowych bazy danych przy użyciu funkcji RESTORE WITH NORECOVERY.

   -- On the server instance that hosts the secondary replica,   
   -- Restore database backups using the WITH NORECOVERY option:  
   RESTORE DATABASE MyDb1   
       FROM DISK = N'\\FILESERVER\SQLbackups\MyDb1.bak'   
       WITH NORECOVERY;  
   GO  
   
   RESTORE DATABASE MyDb2   
       FROM DISK = N'\\FILESERVER\SQLbackups\MyDb2.bak'   
       WITH NORECOVERY;  
   GO 
   

7. Na wystąpieniu serwera z repliką podstawową wykonaj kopię zapasową dziennika transakcji w każdej z podstawowych baz danych.

   Ważne

   Podczas konfigurowania rzeczywistej grupy dostępności zalecamy, aby przed wykonaniem tej kopii zapasowej dziennika wstrzymać zadania tworzenia kopii zapasowej dzienników dla podstawowych baz danych, dopóki nie dołączysz odpowiednich pomocniczych baz danych do grupy dostępności.

   Poniższy przykład kodu tworzy kopię zapasową dziennika transakcji w usłudze MyDb1 i w usłudze MyDb2.

   -- On the server instance that hosts the primary replica,   
   -- Backup the transaction log on each primary database:  
   BACKUP LOG MyDb1   
   TO DISK = N'\\FILESERVER\SQLbackups\MyDb1.bak'   
       WITH NOFORMAT;  
   GO  
   
   BACKUP LOG MyDb2   
   TO DISK = N'\\FILESERVER\SQLbackups\MyDb2.bak'   
       WITH NOFORMAT;  
   GO
   

   Wskazówka

   Zazwyczaj kopię zapasową dziennika należy wykonać dla każdej podstawowej bazy danych i przywrócić ją na odpowiedniej pomocniczej bazie danych, korzystając z funkcji WITH NORECOVERY. Jednak ta kopia zapasowa dziennika może być niepotrzebna, jeśli baza danych właśnie została utworzona i nie utworzono jeszcze żadnej kopii zapasowej dziennika lub model odzyskiwania został właśnie zmieniony z SIMPLE na FULL.

8. Na instancji serwera, która hostuje replikę pomocniczą, zastosuj kopie zapasowe dzienników transakcji do baz danych pomocniczych.

   Poniższy przykład kodu stosuje kopie zapasowe do pomocniczych baz danych MyDb1 i MyDb2 przez przywrócenie kopii zapasowych bazy danych przy użyciu funkcji RESTORE WITH NORECOVERY.

   Ważne

   Podczas przygotowywania rzeczywistej pomocniczej bazy danych, należy zastosować każdą kopię zapasową dziennika utworzoną od czasu kopii zapasowej bazy danych, z której stworzono pomocniczą bazę danych, zaczynając od najwcześniejszej i zawsze używając polecenia RESTORE WITH NORECOVERY. Oczywiście, jeśli przywracasz zarówno pełne, jak i różnicowe kopie zapasowe bazy danych, trzeba zastosować tylko kopie zapasowe dziennika wykonane po wykonaniu różnicowej kopii zapasowej.

   -- Restore the transaction log on each secondary database,  
   -- using the WITH NORECOVERY option:  
   RESTORE LOG MyDb1   
       FROM DISK = N'\\FILESERVER\SQLbackups\MyDb1.bak'   
       WITH FILE=1, NORECOVERY;  
   GO  
   RESTORE LOG MyDb2   
       FROM DISK = N'\\FILESERVER\SQLbackups\MyDb2.bak'   
       WITH FILE=1, NORECOVERY;  
   GO  
   

9. Na instancji serwera, która hostuje replikę wtórną, dołącz nowe bazy danych repliki wtórnej do grupy dostępności.

   Poniższy przykładowy kod dołącza pomocniczą bazę danych MyDb1 , a następnie pomocnicze bazy danych MyDb2 do grupy dostępności MyAG .

   -- On the server instance that hosts the secondary replica,   
   -- join each secondary database to the availability group:  
   ALTER DATABASE MyDb1 SET HADR AVAILABILITY GROUP = MyAG;  
   GO  
   
   ALTER DATABASE MyDb2 SET HADR AVAILABILITY GROUP = MyAG;  
   GO  
   

Kompletny przykład kodu dla przykładowej procedury konfiguracji

Poniższy przykład scala przykłady kodu ze wszystkich kroków przykładowej procedury konfiguracji. Poniższa tabela zawiera podsumowanie wartości symboli zastępczych używanych w tym przykładzie kodu. Aby uzyskać więcej informacji na temat kroków w tym przykładzie kodu, zobacz Wymagania wstępne dotyczące korzystania z przykładowej procedury konfiguracji i przykładowej procedury konfiguracji, we wcześniejszej części tego tematu.

-- on the server instance that will host the primary replica,   
-- create sample databases:  
CREATE DATABASE MyDb1;  
GO  
ALTER DATABASE MyDb1 SET RECOVERY FULL;  
GO  
  
CREATE DATABASE MyDb2;  
GO  
ALTER DATABASE MyDb2 SET RECOVERY FULL;  
GO  
  
-- Backup sample databases:  
BACKUP DATABASE MyDb1   
TO DISK = N'\\FILESERVER\SQLbackups\MyDb1.bak'   
    WITH FORMAT;  
GO  
  
BACKUP DATABASE MyDb2   
TO DISK = N'\\FILESERVER\SQLbackups\MyDb2.bak'   
    WITH FORMAT;  
GO  
  
-- Create the endpoint on the server instance that will host the primary replica:  
CREATE ENDPOINT dbm_endpoint  
    STATE=STARTED   
    AS TCP (LISTENER_PORT=7022)   
    FOR DATABASE_MIRRORING (ROLE=ALL);  
GO  
  
-- Create the endpoint on the server instance that will host the secondary replica:   
CREATE ENDPOINT dbm_endpoint  
    STATE=STARTED   
    AS TCP (LISTENER_PORT=7022)   
    FOR DATABASE_MIRRORING (ROLE=ALL);  
GO  
  
-- If both service accounts run under the same domain account, skip this step. Otherwise,   
-- On the server instance that will host the primary replica,   
-- create a login for the service account   
-- of the server instance that will host the secondary replica, DOMAIN2\user2,   
-- and grant this login connect permissions on the endpoint:  
USE master;  
GO  
CREATE LOGIN [DOMAIN2\user2] FROM WINDOWS;  
GO  
GRANT CONNECT ON ENDPOINT::dbm_endpoint   
   TO [DOMAIN2\user2];  
GO  
  
-- If both service accounts run under the same domain account, skip this step. Otherwise,   
-- On the server instance that will host the secondary replica,  
-- create a login for the service account   
-- of the server instance that will host the primary replica, DOMAIN1\user1,   
-- and grant this login connect permissions on the endpoint:  
USE master;  
GO  
  
CREATE LOGIN [DOMAIN1\user1] FROM WINDOWS;  
GO  
GRANT CONNECT ON ENDPOINT::dbm_endpoint   
   TO [DOMAIN1\user1];  
GO  
  
-- On the server instance that will host the primary replica,   
-- create the availability group, MyAG:  
CREATE AVAILABILITY GROUP MyAG   
   FOR   
      DATABASE MyDB1, MyDB2   
   REPLICA ON   
      'COMPUTER01\AgHostInstance' WITH   
         (  
         ENDPOINT_URL = 'TCP://COMPUTER01.Adventure-Works.com:7022',  
         AVAILABILITY_MODE = SYNCHRONOUS_COMMIT,  
         FAILOVER_MODE = AUTOMATIC  
         ),  
      'COMPUTER02' WITH   
         (  
         ENDPOINT_URL = 'TCP://COMPUTER02.Adventure-Works.com:7022',  
         AVAILABILITY_MODE = SYNCHRONOUS_COMMIT,  
         FAILOVER_MODE = AUTOMATIC  
         );   
GO  
  
-- On the server instance that hosts the secondary replica,   
-- join the secondary replica to the availability group:  
ALTER AVAILABILITY GROUP MyAG JOIN;  
GO  
  
-- Restore database backups onto this server instance, using RESTORE WITH NORECOVERY:  
RESTORE DATABASE MyDb1   
    FROM DISK = N'\\FILESERVER\SQLbackups\MyDb1.bak'   
    WITH NORECOVERY;  
GO  
  
RESTORE DATABASE MyDb2   
    FROM DISK = N'\\FILESERVER\SQLbackups\MyDb2.bak'   
    WITH NORECOVERY;  
GO  
  
-- Back up the transaction log on each primary database:  
BACKUP LOG MyDb1   
TO DISK = N'\\FILESERVER\SQLbackups\MyDb1.bak'   
    WITH NOFORMAT;  
GO  
  
BACKUP LOG MyDb2   
TO DISK = N'\\FILESERVER\SQLbackups\MyDb2.bak'   
    WITH NOFORMAT  
GO  
  
-- Restore the transaction log on each secondary database,  
-- using the WITH NORECOVERY option:  
RESTORE LOG MyDb1   
    FROM DISK = N'\\FILESERVER\SQLbackups\MyDb1.bak'   
    WITH FILE=1, NORECOVERY;  
GO  
RESTORE LOG MyDb2   
    FROM DISK = N'\\FILESERVER\SQLbackups\MyDb2.bak'   
    WITH FILE=1, NORECOVERY;  
GO  
  
-- On the server instance that hosts the secondary replica,   
-- join each secondary database to the availability group:  
ALTER DATABASE MyDb1 SET HADR AVAILABILITY GROUP = MyAG;  
GO  
  
ALTER DATABASE MyDb2 SET HADR AVAILABILITY GROUP = MyAG;  
GO  

Powiązane zadania

Aby skonfigurować właściwości dostępności grupy i repliki

• Zmiana trybu dostępności repliki dostępności (SQL Server)

• Zmień tryb failover repliki dostępności (SQL Server)

• Tworzenie lub konfigurowanie nasłuchiwacza grupy dostępności (SQL Server)

• Skonfiguruj elastyczną politykę awaryjnego przełączania w celu kontrolowania warunków automatycznego awaryjnego przełączania (Always On grupy dostępności)

• Określ adres URL punktu końcowego podczas dodawania lub modyfikowania repliki dostępności (SQL Server)

• Konfiguracja kopii zapasowej na replikach dostępności (SQL Server)

• Konfigurowanie dostępu do repliki dostępności Read-Only (SQL Server)

• Konfigurowanie routingu Read-Only dla grupy dostępności (SQL Server)

• Zmień okres czasu dla repliki dostępności Session-Timeout (SQL Server)

Aby ukończyć konfigurację grupy dostępności

• Dołącz replikę wtórną do grupy dostępności (SQL Server)

• Ręczne przygotowanie pomocniczej bazy danych dla grupy dostępności (SQL Server)

• Dołączenie bazy danych pomocniczej do grupy dostępności (SQL Server)

• Tworzenie lub konfigurowanie nasłuchiwacza grupy dostępności (SQL Server)

Alternatywne sposoby tworzenia grupy dostępności

• Użyj Kreatora Grup Dostępności (SQL Server Management Studio)

• Użyj okna dialogowego Nowa Grupa Dostępności (SQL Server Management Studio)

• Tworzenie grupy dostępności (SQL Server PowerShell)

Aby włączyć zawsze włączone grupy dostępności

• Włączanie i wyłączanie grup dostępności Always On (SQL Server)

Skonfigurować punkt końcowy mirroringu bazy danych

• tworzenie punktu końcowego dublowania bazy danych dla zawsze włączonych grup dostępności (SQL Server PowerShell)

• Tworzenie punktu końcowego mirroringu bazy danych na potrzeby uwierzytelniania systemu Windows (Transact-SQL)

• Użyj certyfikatów na punkt końcowy mirroringu bazy danych (Transact-SQL)

• Określ adres URL punktu końcowego podczas dodawania lub modyfikowania repliki dostępności (SQL Server)

Aby rozwiązać problemy z konfiguracją zawsze włączonych grup dostępności

• Rozwiązywanie problemów z konfiguracją zawsze włączonych grup dostępności (SQL Server)

• Rozwiązywanie problemów z nieudaną operacją Add-File (zawsze włączone grupy dostępności)

Powiązana zawartość

• Blogi :

  Always On — seria szkoleniowa HADRON: wykorzystanie puli roboczej dla baz danych z obsługą HADRON

  Blog Zespołu SQL Server Always On: Oficjalny Blog Zespołu SQL Server Always On

  Blogi inżynierów CSS SQL Server

• oficjalny dokument :

  Przewodnik dotyczący rozwiązań Microsoft SQL Server Always On dla wysokiej dostępności i odzyskiwania po awarii

  Oficjalne opracowania Zespołu Doradczego Klientów SQL Server

Zobacz też

Punkt końcowy mirroringu bazy danych (SQL Server)
Omówienie grup dostępności Always On (SQL Server)
Nasłuchiwacze Grupy Dostępności, Łączność Klienta i Przełączanie Awaryjne Aplikacji (SQL Server)
Wymagania wstępne, Ograniczenia i Zalecenia dotyczące Grup Dostępności Always On (SQL Server)