複数のアクティブな結果セット (MARS)、クエリ通知、ユーザー定義型 (UDT)、または新しい xml データ型など、SQL Server 2005 で導入された新機能を利用するには、ActiveX データ オブジェクト (ADO) を使用する既存のアプリケーションで、データ アクセス プロバイダーとして SQL Server Native Client OLE DB プロバイダーを使用する必要があります。
SQL Server 2005 で導入された新機能を使用する必要がない場合は、SQL Server Native Client OLE DB プロバイダーを使用する必要はありません。現在のデータ アクセス プロバイダー (通常は SQLOLEDB) を引き続き使用できます。 既存のアプリケーションを拡張していて、SQL Server 2005 で導入された新機能を使用する必要がある場合は、SQL Server Native Client OLE DB プロバイダーを使用する必要があります。
注
新しいアプリケーションを開発する場合は、SQL Server Native Client ではなく ADO.NET と .NET Framework Data Provider for SQL Server を使用して、最新バージョンの SQL Server のすべての新機能にアクセスすることを検討することをお勧めします。 .NET Framework Data Provider for SQL Server の詳細については、ADO.NET の .NET Framework SDK ドキュメントを参照してください。
ADO で最新バージョンの SQL Server の新機能を使用できるようにするために、OLE DB のコア機能を拡張する SQL Server Native Client OLE DB プロバイダーにいくつかの機能強化が行われています。 これらの機能強化により、ADO アプリケーションは新しい SQL Server 機能を使用し、SQL Server 2005 で導入された 2 つのデータ型 ( xml と udt) を使用できます。 これらの機能強化では、 varchar、 nvarchar、および varbinary データ型の機能強化も悪用されます。 SQL Server Native Client は、新しいデータ型が ADO と互換性のある方法で公開されるように、ADO アプリケーションで使用するためにDBPROPSET_SQLSERVERDBINIT プロパティ セットにSSPROP_INIT_DATATYPECOMPATIBILITY初期化プロパティを追加します。 さらに、SQL Server Native Client OLE DB プロバイダーでは、接続文字列に設定されている DataTypeCompatibility という名前の新しい接続文字列キーワードも定義されます。
注
既存の ADO アプリケーションは、SQLOLEDB プロバイダーを使用して、XML、UDT、および大きな値のテキストとバイナリ フィールドの値にアクセスして更新できます。 新しい大きな varchar(max)、 nvarchar(max)、 varbinary(max) データ型は、それぞれ ADO 型 adLongVarChar、 adLongVarWChar 、および adLongVarBinary として返されます。 XML 列は adLongVarChar として返され、UDT 列は adVarBinary として返されます。 ただし、SQLOLEDB ではなく SQL Server Native Client OLE DB プロバイダー (SQLNCLI11) を使用する場合は、新しいデータ型が ADO データ型に正しくマップされるように、 DataTypeCompatibility キーワードを必ず "80" に設定する必要があります。
ADO からの SQL Server Native Client の有効化
SQL Server Native Client の使用を有効にするには、ADO アプリケーションで接続文字列に次のキーワードを実装する必要があります。
Provider=SQLNCLI11DataTypeCompatibility=80
SQL Server Native Client でサポートされている ADO 接続文字列キーワードの詳細については、「SQL Server Native Client での 接続文字列キーワードの使用」を参照してください。
次に示す例は、SQL Server Native Client で動作するように完全に有効になっている ADO 接続文字列を確立する例です。MARS 機能の有効化も含まれます。
Dim con As New ADODB.Connection
con.ConnectionString = "Provider=SQLNCLI11;" _
& "Server=(local);" _
& "Database=AdventureWorks;" _
& "Integrated Security=SSPI;" _
& "DataTypeCompatibility=80;" _
& "MARS Connection=True;"
con.Open
例示
次のセクションでは、SQL Server Native Client OLE DB プロバイダーで ADO を使用する方法の例を示します。
XML 列データの取得
この例では、レコードセットを使用して、SQL Server AdventureWorks サンプル データベースの XML 列からデータを取得して表示します。
Dim con As New ADODB.Connection
Dim rst As New ADODB.Recordset
Dim sXMLResult As String
con.ConnectionString = "Provider=SQLNCLI11;" _
& "Server=(local);" _
& "Database=AdventureWorks;" _
& "Integrated Security=SSPI;" _
& "DataTypeCompatibility=80;"
con.Open
' Get the xml data as a recordset.
Set rst.ActiveConnection = con
rst.Source = "SELECT AdditionalContactInfo FROM Person.Contact " _
& "WHERE AdditionalContactInfo IS NOT NULL"
rst.Open
' Display the data in the recordset.
While (Not rst.EOF)
sXMLResult = rst.Fields("AdditionalContactInfo").Value
Debug.Print (sXMLResult)
rst.MoveNext
End While
con.Close
Set con = Nothing
注
XML 列では、レコードセットのフィルター処理はサポートされていません。 使用すると、エラーが返されます。
UDT 列データの取得
この例では、 COMMAND オブジェクトを使用して、UDT を返す SQL クエリを実行し、UDT データを更新した後、新しいデータをデータベースに挿入します。 この例では、 Point UDT がデータベースに既に登録されていることを前提としています。
Dim con As New ADODB.Connection
Dim cmd As New ADODB.Command
Dim rst As New ADODB.Recordset
Dim strOldUDT As String
Dim strNewUDT As String
Dim aryTempUDT() As String
Dim strTempID As String
Dim i As Integer
con.ConnectionString = "Provider=SQLNCLI11;" _
& "Server=(local);" _
& "Database=AdventureWorks;" _
& "Integrated Security=SSPI;" _
& "DataTypeCompatibility=80;"
con.Open
' Get the UDT value.
Set cmd.ActiveConnection = con
cmd.CommandText = "SELECT ID, Pnt FROM dbo.Points.ToString()"
Set rst = cmd.Execute
strTempID = rst.Fields(0).Value
strOldUDT = rst.Fields(1).Value
' Do something with the UDT by adding i to each point.
arytempUDT = Split(strOldUDT, ",")
i = 3
strNewUDT = LTrim(Str(Int(aryTempUDT(0)) + i)) + "," + _
LTrim(Str(Int(aryTempUDT(1)) + i))
' Insert the new value back into the database.
cmd.CommandText = "UPDATE dbo.Points SET Pnt = '" + strNewUDT + _
"' WHERE ID = '" + strTempID + "'"
cmd.Execute
con.Close
Set con = Nothing
MARS の有効化と使用
この例では、SQL Server Native Client OLE DB プロバイダーを介して MARS を有効にするために接続文字列を構築し、同じ接続を使用して実行する 2 つのレコードセット オブジェクトを作成します。
Dim con As New ADODB.Connection
con.ConnectionString = "Provider=SQLNCLI11;" _
& "Server=(local);" _
& "Database=AdventureWorks;" _
& "Integrated Security=SSPI;" _
& "DataTypeCompatibility=80;" _
& "MARS Connection=True;"
con.Open
Dim recordset1 As New ADODB.Recordset
Dim recordset2 As New ADODB.Recordset
Dim recordsaffected As Integer
Set recordset1 = con.Execute("SELECT * FROM Table1", recordsaffected, adCmdText)
Set recordset2 = con.Execute("SELECT * FROM Table2", recordsaffected, adCmdText)
con.Close
Set con = Nothing
以前のバージョンの OLE DB プロバイダーでは、1 つの接続ごとにアクティブな結果セットを 1 つだけ開くことができるため、このコードにより、2 回目の実行時に暗黙的な接続が作成されます。 暗黙的な接続が OLE DB 接続プールにプールされていないため、追加のオーバーヘッドが発生します。 SQL Server Native Client OLE DB プロバイダーによって公開されている MARS 機能を使用すると、1 つの接続で複数のアクティブな結果が得られます。