次の方法で共有

Join 句 (Visual Basic)

2 つのコレクションを 1 つのコレクションに結合します。 結合操作は、一致するキーに基づいており、 Equals 演算子を使用します。

構文

Join element In collection _
  [ joinClause _ ]
  [ groupJoinClause ... _ ]
On key1 Equals key2 [ And key3 Equals key4 [... ]

部品

element 必須。 結合するコレクションのコントロール変数。

collection
必須。 Join演算子の左側で識別されるコレクションと結合するコレクション。 Join句は、別のJoin句または Group Join 句で入れ子にすることができます。

joinClause
任意。 クエリをさらに絞り込むための 1 つ以上の追加の Join 句。

groupJoinClause
任意。 クエリをさらに絞り込むための 1 つ以上の追加の Group Join 句。

key1 Equals key2
必須。 結合するコレクションのキーを識別します。 結合するコレクションのキーを比較するには、 Equals 演算子を使用する必要があります。 And演算子を使用して複数のキーを識別することで、結合条件を組み合わせることができます。 key1 は、 Join 演算子の左側にあるコレクションからである必要があります。 key2 は、 Join 演算子の右側にあるコレクションからである必要があります。

結合条件で使用されるキーには、コレクションから複数の項目を含む式を指定できます。 ただし、各キー式には、それぞれのコレクションの項目のみを含めることができます。

注釈

Join句は、結合されるコレクションの一致するキー値に基づいて 2 つのコレクションを結合します。 結果のコレクションには、 Join 演算子の左側で識別されるコレクションと、 Join 句で識別されるコレクションの値の任意の組み合わせを含めることができます。 クエリは、 Equals 演算子で指定された条件が満たされた結果のみを返します。 これは、SQL の INNER JOIN と同じです。

クエリで複数の Join 句を使用して、2 つ以上のコレクションを 1 つのコレクションに結合できます。

暗黙的な結合を実行して、 Join 句を使用せずにコレクションを結合できます。 これを行うには、From句に複数のIn句を含め、結合に使用するキーを識別するWhere句を指定します。

Group Join句を使用して、コレクションを 1 つの階層コレクションに結合できます。 これは SQL の LEFT OUTER JOIN のようなものです。

例 1

次のコード例では、暗黙的な結合を実行して、顧客の一覧と注文を結合します。

Dim customerIDs() = {"ALFKI", "VICTE", "BLAUS", "TRAIH"}

Dim customerList = From cust In customers, custID In customerIDs
                   Where cust.CustomerID = custID
                   Select cust.CompanyName

For Each companyName In customerList
    Console.WriteLine(companyName)
Next

例 2

次のコード例では、 Join 句を使用して 2 つのコレクションを結合します。

Imports System.Diagnostics

Public Class JoinSample

    Public Sub ListProcesses()
        Dim processDescriptions As New List(Of ProcessDescription)
        processDescriptions.Add(New ProcessDescription With {
                                    .ProcessName = "explorer",
                                    .Description = "Windows Explorer"})
        processDescriptions.Add(New ProcessDescription With {
                                    .ProcessName = "winlogon",
                                    .Description = "Windows Logon"})
        processDescriptions.Add(New ProcessDescription With {
                                    .ProcessName = "cmd",
                                    .Description = "Command Window"})
        processDescriptions.Add(New ProcessDescription With {
                                    .ProcessName = "iexplore",
                                    .Description = "Internet Explorer"})

        Dim processes = From proc In Process.GetProcesses
                        Join desc In processDescriptions
                          On proc.ProcessName Equals desc.ProcessName
                        Select proc.ProcessName, proc.Id, desc.Description

        For Each proc In processes
            Console.WriteLine("{0} ({1}), {2}",
                              proc.ProcessName, proc.Id, proc.Description)
        Next
    End Sub

End Class

Public Class ProcessDescription
    Public ProcessName As String
    Public Description As String
End Class

この例では、次のような出力が生成されます。

winlogon (968), Windows Logon

explorer (2424), File Explorer

cmd (5136), Command Window

例 3

次のコード例では、 Join 句と 2 つのキー列を使用して、2 つのコレクションを結合します。

Imports System.Diagnostics

Public Class JoinSample2

    Public Sub ListProcesses()
        Dim processDescriptions As New List(Of ProcessDescription2)

        ' 8 = Normal priority, 13 = High priority
        processDescriptions.Add(New ProcessDescription2 With {
                                    .ProcessName = "explorer",
                                    .Description = "Windows Explorer",
                                    .Priority = 8})
        processDescriptions.Add(New ProcessDescription2 With {
                                    .ProcessName = "winlogon",
                                    .Description = "Windows Logon",
                                    .Priority = 13})
        processDescriptions.Add(New ProcessDescription2 With {
                                    .ProcessName = "cmd",
                                    .Description = "Command Window",
                                    .Priority = 8})
        processDescriptions.Add(New ProcessDescription2 With {
                                    .ProcessName = "iexplore",
                                    .Description = "Internet Explorer",
                                    .Priority = 8})

        Dim processes = From proc In Process.GetProcesses
                        Join desc In processDescriptions
                          On proc.ProcessName Equals desc.ProcessName And
                             proc.BasePriority Equals desc.Priority
                        Select proc.ProcessName, proc.Id, desc.Description,
                               desc.Priority

        For Each proc In processes
            Console.WriteLine("{0} ({1}), {2}, Priority = {3}",
                              proc.ProcessName,
                              proc.Id,
                              proc.Description,
                              proc.Priority)
        Next
    End Sub

End Class

Public Class ProcessDescription2
    Public ProcessName As String
    Public Description As String
    Public Priority As Integer
End Class

この例では、次のような出力が生成されます。

winlogon (968), Windows Logon, Priority = 13

cmd (700), Command Window, Priority = 8

explorer (2424), File Explorer, Priority = 8

こちらも参照ください