次の方法で共有

GetXmlNamespace 演算子 (Visual Basic)

指定した XML 名前空間プレフィックスに対応する XNamespace オブジェクトを取得します。

構文

GetXmlNamespace(xmlNamespacePrefix)

部品

xmlNamespacePrefix 省略可能です。 XML 名前空間プレフィックスを識別する文字列。 指定する場合、この文字列は有効な XML 識別子である必要があります。 詳細については、「 宣言された XML 要素と属性の名前」を参照してください。 プレフィックスが指定されていない場合は、既定の名前空間が返されます。 既定の名前空間が指定されていない場合は、空の名前空間が返されます。

戻り値

XML 名前空間プレフィックスに対応する XNamespace オブジェクト。

注釈

GetXmlNamespace演算子は、XML 名前空間プレフィックス xmlNamespacePrefixに対応するXNamespace オブジェクトを取得します。

XML リテラルおよび XML 軸プロパティでは、XML 名前空間プレフィックスを直接使用できます。 ただし、コードで使用する前に、 GetXmlNamespace 演算子を使用して名前空間プレフィックスを XNamespace オブジェクトに変換する必要があります。 修飾されていない要素名を XNamespace オブジェクトに追加して、多くの LINQ to XML メソッドが必要とする完全修飾 XName オブジェクトを取得できます。

例

次の例では、 ns を XML 名前空間プレフィックスとしてインポートします。 その後、名前空間のプレフィックスを使用して XML リテラルを作成し、修飾名 ns:phoneを持つ最初の子ノードにアクセスします。 その後、その子ノードを ShowName サブルーチンに渡します。このサブルーチンは、 GetXmlNamespace 演算子を使用して修飾名を作成します。 その後、 ShowName サブルーチンは修飾名を Ancestors メソッドに渡して、親 ns:contact ノードを取得します。

' Place Imports statements at the top of your program.  
Imports <xmlns:ns="http://SomeNamespace">

Module GetXmlNamespaceSample

    Sub RunSample()

        ' Create test by using a global XML namespace prefix. 

        Dim contact = 
            <ns:contact>
                <ns:name>Patrick Hines</ns:name>
                <ns:phone ns:type="home">206-555-0144</ns:phone>
                <ns:phone ns:type="work">425-555-0145</ns:phone>
            </ns:contact>

        ShowName(contact.<ns:phone>(0))
    End Sub

    Sub ShowName(ByVal phone As XElement)
        Dim qualifiedName = GetXmlNamespace(ns) + "contact"
        Dim contact = phone.Ancestors(qualifiedName)(0)
        Console.WriteLine("Name: " & contact.<ns:name>.Value)
    End Sub

End Module

TestGetXmlNamespace.RunSample()を呼び出すと、次のテキストを含むメッセージ ボックスが表示されます。

Name: Patrick Hines

こちらも参照ください