文字列関数 (Visual Basic)

次の表に、文字列を検索および操作するために visual Basic が Microsoft.VisualBasic.Strings クラスで提供する関数を示します。 これらは Visual Basic 組み込み関数と見なすことができます。つまり、例に示すように、それらをクラスの明示的なメンバーとして呼び出す必要はありません。 System.String クラスでは、追加のメソッドと場合によっては補完的なメソッドを使用できます。

Option Compare ステートメントを使用すると、システムのロケール (Text) または文字の内部バイナリ表現 (Binary) によって決定される、大文字と小文字を区別しないテキストの並べ替え順序を使用して文字列を比較するかどうかを設定できます。 既定のテキスト比較方法は Binary。

例: UCase

この例では、 UCase 関数を使用して、文字列の大文字のバージョンを返します。

' String to convert.
Dim lowerCase As String = "Hello World 1234"
' Returns "HELLO WORLD 1234".
Dim upperCase As String = UCase(lowerCase)

例: LTrim

この例では、 LTrim 関数を使用して先頭のスペースを削除し、 RTrim 関数を使用して文字列変数から末尾のスペースを削除します。 Trim関数を使用して、両方の種類のスペースを削除します。

' Initializes string.
Dim testString As String = "  <-Trim->  "
Dim trimString As String
' Returns "<-Trim->  ".
trimString = LTrim(testString)
' Returns "  <-Trim->".
trimString = RTrim(testString)
' Returns "<-Trim->".
trimString = LTrim(RTrim(testString))
' Using the Trim function alone achieves the same result.
' Returns "<-Trim->".
trimString = Trim(testString)

例: Mid

この例では、 Mid 関数を使用して、文字列から指定した文字数を返します。

' Creates text string.
Dim testString As String = "Mid Function Demo"
' Returns "Mid".
Dim firstWord As String = Mid(testString, 1, 3)
' Returns "Demo".
Dim lastWord As String = Mid(testString, 14, 4)
' Returns "Function Demo".
Dim midWords As String = Mid(testString, 5)

例: Len

この例では、 Len を使用して文字列内の文字数を返します。

' Initializes variable.
Dim testString As String = "Hello World"
' Returns 11.
Dim testLen As Integer = Len(testString)

例: InStr

この例では、 InStr 関数を使用して、別の文字列内で最初に出現する文字列の位置を返します。

' String to search in.
Dim searchString As String = "XXpXXpXXPXXP"
' Search for "P".
Dim searchChar As String = "P"

Dim testPos As Integer
' A textual comparison starting at position 4. Returns 6.
testPos = InStr(4, searchString, searchChar, CompareMethod.Text)

' A binary comparison starting at position 1. Returns 9.
testPos = InStr(1, SearchString, SearchChar, CompareMethod.Binary)

' If Option Compare is not set, or set to Binary, return 9.
' If Option Compare is set to Text, returns 3.
testPos = InStr(searchString, searchChar)

' Returns 0.
testPos = InStr(1, searchString, "W")

例: 書式

この例では、 Format 関数を使用して、 String 形式とユーザー定義形式の両方を使用して値を書式設定するさまざまな使用方法を示します。 日付区切り記号 (/)、時刻区切り記号 (:)、AM/PM インジケーター (t と tt) の場合、システムによって表示される実際の書式設定された出力は、コードで使用されているロケール設定によって異なります。 開発環境で時刻と日付が表示される場合は、コード ロケールの短い時刻形式と短い日付形式が使用されます。

Dim testDateTime As Date = #1/27/2001 5:04:23 PM#
Dim testStr As String
' Returns current system time in the system-defined long time format.
testStr = Format(Now(), "Long Time")
' Returns current system date in the system-defined long date format.
testStr = Format(Now(), "Long Date")
' Also returns current system date in the system-defined long date 
' format, using the single letter code for the format.
testStr = Format(Now(), "D")

' Returns the value of testDateTime in user-defined date/time formats.
' Returns "5:4:23".
testStr = Format(testDateTime, "h:m:s")
' Returns "05:04:23 PM".
testStr = Format(testDateTime, "hh:mm:ss tt")
' Returns "Saturday, Jan 27 2001".
testStr = Format(testDateTime, "dddd, MMM d yyyy")
' Returns "17:04:23".
testStr = Format(testDateTime, "HH:mm:ss")
' Returns "23".
testStr = Format(23)

' User-defined numeric formats.
' Returns "5,459.40".
testStr = Format(5459.4, "##,##0.00")
' Returns "334.90".
testStr = Format(334.9, "###0.00")
' Returns "500.00%".
testStr = Format(5, "0.00%")

こちらも参照ください

• キーワード
• Visual Basic ランタイム ライブラリのメンバー
• 文字列操作の概要
• System.String クラス メソッド