Slices

この記事では、既存の F# 型からスライスを取得する方法と、独自のスライスを定義する方法について説明します。

F# では、スライスは任意のデータ型のサブセットです。 スライスは インデクサーに似ていますが、基になるデータ構造から 1 つの値を生成する代わりに、複数の値を生成します。 スライスでは、 .. 演算子構文を使用して、データ型で指定されたインデックスの範囲を選択します。 詳細については、 ループ式のリファレンス記事を参照してください。

F# では現在、文字列、リスト、配列、および多次元 (2D、3D、4D) 配列のスライスが組み込まれています。 スライスは、F# の配列とリストで最も一般的に使用されます。 カスタム データ型にスライスを追加するには、型定義またはスコープ内の型拡張でGetSlice メソッドを使用します。

F# リストと配列のスライス

スライスされる最も一般的なデータ型は、F# リストと配列です。 次の例では、リストをスライスする方法を示します。

// Generate a list of 100 integers
let fullList = [ 1 .. 100 ]

// Create a slice from indices 1-5 (inclusive)
let smallSlice = fullList[1..5]
printfn $"Small slice: {smallSlice}"

// Create a slice from the beginning to index 5 (inclusive)
let unboundedBeginning = fullList[..5]
printfn $"Unbounded beginning slice: {unboundedBeginning}"

// Create a slice from an index to the end of the list
let unboundedEnd = fullList[94..]
printfn $"Unbounded end slice: {unboundedEnd}"

配列のスライスは、リストのスライスに似ています。

// Generate an array of 100 integers
let fullArray = [| 1 .. 100 |]

// Create a slice from indices 1-5 (inclusive)
let smallSlice = fullArray[1..5]
printfn $"Small slice: {smallSlice}"

// Create a slice from the beginning to index 5 (inclusive)
let unboundedBeginning = fullArray[..5]
printfn $"Unbounded beginning slice: {unboundedBeginning}"

// Create a slice from an index to the end of the list
let unboundedEnd = fullArray[94..]
printfn $"Unbounded end slice: {unboundedEnd}"

F# 6 より前では、スライスでは構文 expr.[start..finish] を追加の .と共に使用しました。 選択した場合でも、この構文を使用できます。 詳細については、 RFC FS-1110 を参照してください。

多次元配列のスライス

F# では、F# コア ライブラリの多次元配列がサポートされています。 1 次元配列と同様に、多次元配列のスライスも役立ちます。 ただし、追加ディメンションの導入では、特定の行と列のスライスを取得できるように、少し異なる構文が必要です。

次の例では、2D 配列をスライスする方法を示します。

// Generate a 3x3 2D matrix
let A = array2D [[1;2;3];[4;5;6];[7;8;9]]
printfn $"Full matrix:\n {A}"

// Take the first row
let row0 = A[0,*]
printfn $"{row0}"

// Take the first column
let col0 = A[*,0]
printfn $"{col0}"

// Take all rows but only two columns
let subA = A[*,0..1]
printfn $"{subA}"

// Take two rows and all columns
let subA' = A[0..1,*]
printfn $"{subA}"

// Slice a 2x2 matrix out of the full 3x3 matrix
let twoByTwo = A[0..1,0..1]
printfn $"{twoByTwo}"

他のデータ構造のスライスの定義

F# コア ライブラリは、限られた種類のセットのスライスを定義します。 より多くのデータ型のスライスを定義する場合は、型定義自体または型拡張で定義できます。

たとえば、便利なデータ操作を可能にするために、 ArraySegment<T> クラスのスライスを定義する方法を次に示します。

open System

type ArraySegment<'TItem> with
    member segment.GetSlice(start, finish) =
        let start = defaultArg start 0
        let finish = defaultArg finish segment.Count
        ArraySegment(segment.Array, segment.Offset + start, finish - start)

let arr = ArraySegment [| 1 .. 10 |]
let slice = arr[2..5] //[ 3; 4; 5]

Span<T>型とReadOnlySpan<T>型を使用する別の例:

open System

type ReadOnlySpan<'T> with
    member sp.GetSlice(startIdx, endIdx) =
        let s = defaultArg startIdx 0
        let e = defaultArg endIdx sp.Length
        sp.Slice(s, e - s)

type Span<'T> with
    member sp.GetSlice(startIdx, endIdx) =
        let s = defaultArg startIdx 0
        let e = defaultArg endIdx sp.Length
        sp.Slice(s, e - s)

let printSpan (sp: Span<int>) =
    let arr = sp.ToArray()
    printfn $"{arr}"

let sp = [| 1; 2; 3; 4; 5 |].AsSpan()
printSpan sp[0..] // [|1; 2; 3; 4; 5|]
printSpan sp[..5] // [|1; 2; 3; 4; 5|]
printSpan sp[0..3] // [|1; 2; 3|]
printSpan sp[1..3] // |2; 3|]

組み込みの F# スライスはエンド インクルーシブです

F# のすべての組み込みスライスは、両端を含みます。つまり、上限はスライスに含まれます。 開始インデックス x と終了インデックス yのある特定のスライスの場合、結果のスライスには y 番目 の値が含まれます。

// Define a new list
let xs = [1 .. 10]

printfn $"{xs[2..5]}" // Includes the 5th index

組み込みの F# 空のスライス

F# リスト、配列、シーケンス、文字列、多次元 (2D、3D、4D) 配列は、構文が存在しないスライスを生成できる場合は、すべて空のスライスを生成します。

次の例を確認してください。

let l = [ 1..10 ]
let a = [| 1..10 |]
let s = "hello!"

let emptyList = l[-2..(-1)]
let emptyArray = a[-2..(-1)]
let emptyString = s[-2..(-1)]

3D 配列と 4D 配列の固定インデックス スライス

F# 3D 配列と 4D 配列の場合、特定のインデックスを "修正" し、そのインデックスを固定して他のディメンションをスライスできます。

これを説明するために、次の 3D 配列について考えてみましょう。

z = 0

z = 1

配列からスライス [| 4; 5 |] を抽出する場合は、固定インデックス スライスを使用します。

let dim = 2
let m = Array3D.zeroCreate<int> dim dim dim

let mutable count = 0

for z in 0..dim-1 do
    for y in 0..dim-1 do
        for x in 0..dim-1 do
            m[x,y,z] <- count
            count <- count + 1

// Now let's get the [4;5] slice!
m[*, 0, 1]

最後の行は、3D 配列の y インデックスと z インデックスを修正し、行列に対応する残りの x 値を受け取ります。

こちらも参照ください

• インデックス付きプロパティ