Annuler des tâches asynchrones après une période de temps (Visual Basic)

Vous pouvez annuler une opération asynchrone après une période de temps à l’aide de la CancellationTokenSource.CancelAfter méthode si vous ne souhaitez pas attendre la fin de l’opération. Cette méthode planifie l’annulation de toutes les tâches associées qui ne sont pas terminées au cours de la période désignée par l’expression CancelAfter .

Cet exemple ajoute au code développé dans Annuler une tâche asynchrone ou une liste de tâches (Visual Basic) pour télécharger une liste de sites web et afficher la longueur du contenu de chacun d’eux.

Téléchargement de l’exemple

Vous pouvez télécharger le projet WPF (Windows Presentation Foundation) complet à partir de l’exemple Async : ajuster votre application , puis suivre ces étapes.

1. Décompressez le fichier que vous avez téléchargé, puis démarrez Visual Studio.

2. Dans la barre de menus, choisissez Fichier, Ouvrir, Projet/Solution.

3. Dans la boîte de dialogue Ouvrir un projet , ouvrez le dossier contenant l’exemple de code que vous avez décompressé, puis ouvrez le fichier de solution (.sln) pour AsyncFineTuningVB.

4. Dans l’Explorateur de solutions, ouvrez le menu contextuel du projet CancelAfterTime , puis choisissez Définir comme projet de démarrage.

5. Choisissez la clé F5 pour exécuter le projet.

   Choisissez les touches Ctrl+F5 pour exécuter le projet sans le déboguer.

6. Exécutez le programme plusieurs fois pour vérifier que la sortie peut afficher la sortie pour tous les sites web, aucun site web ou certains sites web.

Si vous ne souhaitez pas télécharger le projet, vous pouvez consulter le fichier MainWindow.xaml.vb à la fin de cette rubrique.

Construction de l'exemple

L’exemple de cette rubrique ajoute au projet développé dans Annuler une tâche asynchrone ou une liste de tâches (Visual Basic) pour annuler une liste de tâches. L’exemple utilise la même interface utilisateur, même si le bouton Annuler n’est pas utilisé explicitement.

Pour générer l’exemple vous-même, suivez les instructions de la section « Téléchargement de l’exemple », mais choisissez CancelAListOfTasks comme projet de démarrage. Ajoutez les modifications de cette rubrique à ce projet.

Pour spécifier une durée maximale avant que les tâches soient marquées comme annulées, ajoutez un appel à CancelAfterstartButton_Click, comme l’illustre l’exemple suivant. L’ajout est marqué avec des astérisques.

Private Async Sub startButton_Click(sender As Object, e As RoutedEventArgs)

    ' Instantiate the CancellationTokenSource.
    cts = New CancellationTokenSource()

    resultsTextBox.Clear()

    Try
        ' ***Set up the CancellationTokenSource to cancel after 2.5 seconds. (You
        ' can adjust the time.)
        cts.CancelAfter(2500)

        Await AccessTheWebAsync(cts.Token)
        resultsTextBox.Text &= vbCrLf & "Downloads complete."

    Catch ex As OperationCanceledException
        resultsTextBox.Text &= vbCrLf & "Downloads canceled." & vbCrLf

    Catch ex As Exception
        resultsTextBox.Text &= vbCrLf & "Downloads failed." & vbCrLf
    End Try

    ' Set the CancellationTokenSource to Nothing when the download is complete.
    cts = Nothing
End Sub

Exécutez le programme plusieurs fois pour vérifier que la sortie peut afficher la sortie pour tous les sites web, aucun site web ou certains sites web. La sortie suivante est un exemple :

Length of the downloaded string: 35990.

Length of the downloaded string: 407399.

Length of the downloaded string: 226091.

Downloads canceled.

Exemple complet

Le code suivant est le texte complet du fichier MainWindow.xaml.vb pour l’exemple. Les astérisques marquent les éléments qui ont été ajoutés pour cet exemple.

Notez que vous devez ajouter une référence pour System.Net.Http.

Vous pouvez télécharger le projet à partir de l’exemple Async : ajuster votre application.

' Add an Imports directive and a reference for System.Net.Http.
Imports System.Net.Http

' Add the following Imports directive for System.Threading.
Imports System.Threading

Class MainWindow

    ' Declare a System.Threading.CancellationTokenSource.
    Dim cts As CancellationTokenSource

    Private Async Sub startButton_Click(sender As Object, e As RoutedEventArgs)

        ' Instantiate the CancellationTokenSource.
        cts = New CancellationTokenSource()

        resultsTextBox.Clear()

        Try
            ' ***Set up the CancellationTokenSource to cancel after 2.5 seconds. (You
            ' can adjust the time.)
            cts.CancelAfter(2500)

            Await AccessTheWebAsync(cts.Token)
            resultsTextBox.Text &= vbCrLf & "Downloads complete."

        Catch ex As OperationCanceledException
            resultsTextBox.Text &= vbCrLf & "Downloads canceled." & vbCrLf

        Catch ex As Exception
            resultsTextBox.Text &= vbCrLf & "Downloads failed." & vbCrLf
        End Try

        ' Set the CancellationTokenSource to Nothing when the download is complete.
        cts = Nothing
    End Sub

    ' You can still include a Cancel button if you want to.
    Private Sub cancelButton_Click(sender As Object, e As RoutedEventArgs)

        If cts IsNot Nothing Then
            cts.Cancel()
        End If
    End Sub

    ' Provide a parameter for the CancellationToken.
    ' Change the return type to Task because the method has no return statement.
    Async Function AccessTheWebAsync(ct As CancellationToken) As Task

        Dim client As HttpClient = New HttpClient()

        ' Call SetUpURLList to make a list of web addresses.
        Dim urlList As List(Of String) = SetUpURLList()

        ' Process each element in the list of web addresses.
        For Each url In urlList
            ' GetAsync returns a Task(Of HttpResponseMessage).
            ' Argument ct carries the message if the Cancel button is chosen.
            ' Note that the Cancel button can cancel all remaining downloads.
            Dim response As HttpResponseMessage = Await client.GetAsync(url, ct)

            ' Retrieve the website contents from the HttpResponseMessage.
            Dim urlContents As Byte() = Await response.Content.ReadAsByteArrayAsync()

            resultsTextBox.Text &=
                vbCrLf & $"Length of the downloaded string: {urlContents.Length}." & vbCrLf
        Next
    End Function

    ' Add a method that creates a list of web addresses.
    Private Function SetUpURLList() As List(Of String)

        Dim urls = New List(Of String) From
            {
                "https://msdn.microsoft.com",
                "https://msdn.microsoft.com/library/hh290138.aspx",
                "https://msdn.microsoft.com/library/hh290140.aspx",
                "https://msdn.microsoft.com/library/dd470362.aspx",
                "https://msdn.microsoft.com/library/aa578028.aspx",
                "https://msdn.microsoft.com/library/ms404677.aspx",
                "https://msdn.microsoft.com/library/ff730837.aspx"
            }
        Return urls
    End Function

End Class

' Sample output:

' Length of the downloaded string: 35990.

' Length of the downloaded string: 407399.

' Length of the downloaded string: 226091.

' Downloads canceled.

Voir aussi

• Programmation asynchrone avec Async et Await (Visual Basic)
• Procédure pas à pas : accès au web à l’aide d’Async et Await (Visual Basic)
• Annuler une tâche asynchrone ou une liste de tâches (Visual Basic)
• Fine-Tuning votre application asynchrone (Visual Basic)
• Exemple asynchrone : réglage précis de votre application