Imports, instruction (espace de noms et type.NET)

Permet aux noms de types d’être référencés sans qualification d’espace de noms.

Syntaxe

Imports [ aliasname = ] namespace
' -or-
Imports [ aliasname = ] namespace.element

Pièces

Remarques

L’instruction Imports permet aux types contenus dans un espace de noms donné d’être référencés directement.

Vous pouvez fournir un nom d’espace de noms unique ou une chaîne d’espaces de noms imbriqués. Chaque espace de noms imbriqué est séparé de l’espace de noms de niveau supérieur suivant par un point (.), comme l’illustre l’exemple suivant :

Imports System.Collections.Generic

Chaque fichier source peut contenir n’importe quel nombre d’instructions Imports . Ces déclarations doivent suivre toutes les déclarations d’option, telles que l’instruction Option Strict , et elles doivent précéder les déclarations d’éléments de programmation, telles que Module les instructions ou Class les instructions.

Vous ne pouvez utiliser Imports qu’au niveau du fichier. Cela signifie que le contexte de déclaration pour l’importation doit être un fichier source et ne peut pas être un espace de noms, une classe, une structure, un module, une interface, une procédure ou un bloc.

Notez que l’instruction Imports ne rend pas les éléments d’autres projets et assemblys disponibles pour votre projet. L’importation ne prend pas la place de la définition d’une référence. Elle supprime uniquement la nécessité de qualifier les noms qui sont déjà disponibles pour votre projet. Pour plus d’informations, consultez « Importation d’éléments contenant des éléments » dans les références aux éléments déclarés.

Importer des alias

Un alias d’importation définit l’alias d’un espace de noms ou d’un type. Les alias d’importation sont utiles lorsque vous devez utiliser des éléments portant le même nom que celui déclaré dans un ou plusieurs espaces de noms. Pour plus d’informations et un exemple, consultez « Qualification d’un nom d’élément » dans Références aux éléments déclarés.

Vous ne devez pas déclarer un membre au niveau du module portant le même nom que aliasname. Si vous le faites, le compilateur Visual Basic utilise aliasname uniquement pour le membre déclaré et ne le reconnaît plus comme un alias d’importation.

Bien que la syntaxe utilisée pour déclarer un alias d’importation soit similaire à celle utilisée pour l’importation d’un préfixe d’espace de noms XML, les résultats sont différents. Un alias d’importation peut être utilisé comme expression dans votre code, tandis qu’un préfixe d’espace de noms XML ne peut être utilisé que dans les littéraux XML ou les propriétés d’axe XML comme préfixe pour un nom d’élément ou d’attribut qualifié.

Noms d’éléments

Si vous fournissez element, il doit représenter un élément conteneur, autrement dit, un élément de programmation qui peut contenir d’autres éléments. Les éléments de conteneur incluent des classes, des structures, des modules, des interfaces et des énumérations.

L’étendue des éléments mis à disposition par une Imports instruction varie selon que vous spécifiez element. Si vous spécifiez uniquement , tous les membres nommés de manière unique namespacede cet espace de noms et les membres des éléments de conteneur au sein de cet espace de noms sont disponibles sans qualification. Si vous spécifiez les deux namespace et element, seuls les membres de cet élément sont disponibles sans qualification.

Exemple 1

L’exemple suivant retourne tous les dossiers du répertoire C :\ à l’aide de la DirectoryInfo classe :

Le code n’a pas Imports d’instructions en haut du fichier. Par conséquent, les références StringBuilderet CrLf les DirectoryInforéférences sont toutes complètes avec les espaces de noms.

Public Function GetFolders() As String
    ' Create a new StringBuilder, which is used
    ' to efficiently build strings.
    Dim sb As New System.Text.StringBuilder

    Dim dInfo As New System.IO.DirectoryInfo("c:\")

    ' Obtain an array of directories, and iterate through
    ' the array.
    For Each dir As System.IO.DirectoryInfo In dInfo.GetDirectories()
        sb.Append(dir.Name)
        sb.Append(Microsoft.VisualBasic.ControlChars.CrLf)
    Next

    Return sb.ToString
End Function

Exemple 2

L’exemple suivant inclut des Imports instructions pour les espaces de noms référencés. Par conséquent, les types n’ont pas besoin d’être complets avec les espaces de noms.

' Place Imports statements at the top of your program.
Imports System.Text
Imports System.IO
Imports Microsoft.VisualBasic.ControlChars

Public Function GetFolders() As String
    Dim sb As New StringBuilder

    Dim dInfo As New DirectoryInfo("c:\")
    For Each dir As DirectoryInfo In dInfo.GetDirectories()
        sb.Append(dir.Name)
        sb.Append(CrLf)
    Next

    Return sb.ToString
End Function

Exemple 3

L’exemple suivant inclut des Imports instructions qui créent des alias pour les espaces de noms référencés. Les types sont qualifiés avec les alias.

Imports systxt = System.Text
Imports sysio = System.IO
Imports ch = Microsoft.VisualBasic.ControlChars

Public Function GetFolders() As String
    Dim sb As New systxt.StringBuilder

    Dim dInfo As New sysio.DirectoryInfo("c:\")
    For Each dir As sysio.DirectoryInfo In dInfo.GetDirectories()
        sb.Append(dir.Name)
        sb.Append(ch.CrLf)
    Next

    Return sb.ToString
End Function

Exemple 4

L’exemple suivant inclut des Imports instructions qui créent des alias pour les types référencés. Les alias sont utilisés pour spécifier les types.

Imports strbld = System.Text.StringBuilder
Imports dirinf = System.IO.DirectoryInfo

Public Function GetFolders() As String
    Dim sb As New strbld

    Dim dInfo As New dirinf("c:\")
    For Each dir As dirinf In dInfo.GetDirectories()
        sb.Append(dir.Name)
        sb.Append(ControlChars.CrLf)
    Next

    Return sb.ToString
End Function

Voir aussi

• Namespace (instruction)
• Espaces de noms dans Visual Basic
• Références et Déclaration des Imports
• Imports, instruction (espace de noms XML)
• Références aux éléments déclarés